Foro Excel

Tengo dos macros en dos botones, cada uno de ellos me descarga unos valores de celda en un libro o en otro según una elección que le doy yo y quería unificar a un sólo botón que según mi elección eligiera una macro o la otra para transferir esos resultados a uno de los dos libros. Alguien me puede poner un ejm para ayudarme. Gracias.

hola, raul !

puedes ejecutar varias macros (o sub-rutinas) desde una principal detectando si la ejecucion se realiza combinando algunas teclas con el apoyo de algunas llamadas a las API's (p.e.)

Código: Seleccionar todo

' otbenemos el estado (pulsada o no) de la tecla "pasada" como argumento "vKey" '
Private Declare Function TeclaPulsada _
  Lib "user32" Alias "GetAsyncKeyState" (ByVal vKey As Long) As Integer

' usamos la llamada anterior para preguntar por el estado de 2 teclas (Shift y Control) '
Private Function Teclas() As Integer
  Dim Pulsadas As Integer, May As Boolean, Ctrl As Boolean
  May = (TeclaPulsada(vbKeyShift) And &H8000)
  Ctrl = (TeclaPulsada(vbKeyControl) And &H8000)
  Pulsadas = Pulsadas - May
  Pulsadas = Pulsadas - (Ctrl * 2)
  Teclas = Pulsadas
End Function

' la siguiente macro de prueba te dira cual(es) tecla(s) presionas al momento de ejecutarla '
Sub ProbandoTeclas()
  Dim CualTecla As String
  Select Case Teclas
    Case 0: CualTecla = "más vale solo... que mal acompañado."
    Case 1: CualTecla = "pulsando la tecla Mayúsculas."
    Case 2: CualTecla = "pulsando la tecla Control."
    Case 3: CualTecla = "pulsando las teclas Mayúsculas y Control"
  End Select
  MsgBox "Este código se está ejecutando ..." & vbCr & CualTecla
End Sub

solo necesitas cambiar los Case (0 a n) por las llamadas a las sub-rutinas apropiadas

si requieres verificar mas (u otras) teclas, pregunta por ellas en la funcion "Teclas"
=> OBSERVA como se acumulan (o suman) las teclas solicitadas ...
al preguntar (solamente) por dos teclas, debo esperar CUATRO (posibles) resultados (0 a 3):
0 = Ninguna pulsada
1 = SOLO la primera
2 = SOLO la segunda
3 = AMBAS (la suma de 1 + 2)

si necesitaras preguntar por TRES teclas, las (posibles) combinaciones serian OCHO (0 a 7)
0 = NINGUNA
1 = SOLO la primera
2 = SOLO la segunda
3 = LAS DOS PRIMERAS (la suma de 1 + 2)
4 = SOLO la tercera
5 = la primera CON la tercera (la suma de 1 + 4)
6 = la segunda CON la tercera (la suma de 2 + 4)
7 = LAS TRES (la suma de 1 + 2 + 4)

saludos,
hector.

Hola Hector,
Antes de nada gracias por prestarme un rato de tu tiempo. La verdad es que me parece muy interesante tu aportación pero quizás lo que busco es más simple. Tengo dos macros y un cuadro combinado que va desde el 1 al 7 , necesito que si en una celda por ejm AG9 aparece el 4 siga una macro y otro número la otra macro.
No se si ayuda mucho mi explicación.
Gracias

Pongo un ejemplo

hola, raul !

... lo que busco es más simple. Tengo dos macros y un cuadro combinado que va desde el 1 al 7 , necesito que si en una celda por ejm AG9 aparece el 4 siga una macro y otro número la otra macro.

solo necesitas una nueva macro que haga uso de las existentes dependiendo del valor en la celda [AG9], p.e.

Código: Seleccionar todo

Sub Cual_Macro()
  If Worksheets("control cm").Range("ag9") = 4 _
    Then Transferir_Datos_UVA _
    Else Transferir_Datos_Control
End Sub

saludos,
hector.

Hasta el año próximo (El lunes pero suena raro) no podré verificar que va bien pero las pruebas que he realizado en casa me dan OK, así que, mil gracias amigo. Una cosa que parece tan fácil y no sabía como hacer que funcionara y lo has solucionado con 5 lineas.
Gracias de nuevo

Bien, funciona a la perfección, gracias Héctor. Incluso la he utilizado para otra cosa, sólo una última pregunta. Se me ocurre que puedo dar más utilidad a la forma de selección de macros, partiendo de tu información, pero desconozco como hacerlo.

P.e. si tengo la celda [AG9] con valor 4 lanza la macro: Transferir_Datos_UVA
Con valor 3 la macro: Transferir_Datos_Control
Con valor 5 la macro: Transferir_Datos_Posicion
Etc...

¿Es esto posible?
Gracias de nuevo.