Foro Excel

Perdon por la pregunta, pero sucede que trato de que en libro de excel con una sola clave pueda proteger todas las hojas, cuidando ciertas celdas para que no se puedan modificar,
Pero cuando protejo desde "PROTEGER LIBRO", voy a las hojas y no están protegidas.
¿COMO SE HACE??ME PODRIAN AYUDAR?

Hola Mauro:

Lo que debes hacer es utilizar la opción Proteger hoja..., que se encuentra en el menú Herramientas / Proteger / Proteger hoja...
Las celdas que quieras proteger deben estar bloqueadas, para bloquearlas debes seleccionar las celdas a bloquear ir al menú Formato / Celdas... una vez ahí­ seleccionar la pestaña Proteger y seleccionar Bloqueada.

Ahora puedes proteger tu hoja con contraseña.

Espere sea lo que quieras y que me comentes como te fue.

Irivera_07:
Lo que tu me comentas ya lo tengo hecho en cada hoja, pero lo que necesito saber es como mediante una sola clave proteger las 6 hojas que conforman el libro. Me explico? Desde ya gracias por tu interés.

Adjunto un libro que contiene el siguiente codigo:

Código: Seleccionar todo

Sub Proteger()
Dim HojaInicial As String, Clave As String
On Error GoTo Mensaje
  Clave = InputBox("Escribe la clave para proteger: ", "Proteger")
'PROTEGER LIBRO
  ActiveWorkbook.Protect Password:=Clave, Structure:=True, Windows:=False
'PROTEGER HOJAS
  Application.ScreenUpdating = False 'Para congelar la pantalla
  HojaInicial = ActiveSheet.Name 'Guardamos el nombre de la hoja de inicio
  For Each Sheet In Sheets
    Sheet.Protect Password:=Clave, DrawingObjects:=True, Contents:=True, Scenarios:=True
  Next
  ActiveWorkbook.Sheets(HojaInicial).Select 'Regresamos a la hoja inicial
  Application.ScreenUpdating = True 'Para actualizar la pantalla
  Exit Sub

Mensaje:
  MsgBox "El proceso se interrumpio porque la contraseña no es valida para todos los elementos.", vbCritical + vbOKOnly, "Proceso Interrumpido"
End Sub

Sub Desproteger()
Dim HojaInicial As String, Clave As String
On Error GoTo Mensaje
  Clave = InputBox("Escribe la clave para desproteger: ", "Desproteger")
'DESPROTEGER LIBRO
  ActiveWorkbook.Unprotect Password:=Clave
'DESPROTEGER HOJAS
  Application.ScreenUpdating = False 'Para congelar la pantalla
  HojaInicial = ActiveSheet.Name 'Guardamos el nombre de la hoja de inicio
  For Each Sheet In Sheets
    Sheet.Unprotect Password:=Clave
  Next
  ActiveWorkbook.Sheets(HojaInicial).Select 'Regresamos a la hoja inicial
  Application.ScreenUpdating = True 'Para actualizar la pantalla
  Exit Sub

Mensaje:
  MsgBox "El proceso se interrumpio porque la contraseña no es valida para todos los elementos.", vbCritical + vbOKOnly, "Proceso Interrumpido"
End Sub


Debes habilitar las macros al abrir este libro
Presiona Alt + F8 para ver la lista de macros disponibles

Para Proteger todo:
Ejecuta la macro "Proteger" y escribe la clave
Verifica que todas las hojas esten protegidas e incluso el libro

Para desproteger todo:
Ejecuta la macro "Desproteger" y escribe la clave
Verifica que todas las hojas esten desprotegidas e incluso el libro

Prueba ejecutando las macros desde cualquier hoja del libro, siempre te devolvera a la misma hoja inicial. Si te aparece un error al desproteger, es porque alguna hoja o el libro esta protegido con una contraseña diferente a la que ingresaste, y en ese momento se interrumpio la macro. Es posible que haya mas hojas con la contraseña que indicaste, sin embargo no se desprotegieron porque antes de llegar a ellas se interrumpio el proceso.

Nos cuentas si te resulto.